  //%attributes = {"lang":"en"} comment added and reserved by 4D.
C_LONGINT:C283(NumTable;BarInformation)
ARRAY TEXT:C222(LbTableName;0x0000)
ARRAY TEXT:C222(LbFormName;0x0000)
ARRAY TEXT:C222(LbObject;0x0000)
ARRAY TEXT:C222(LbObjectType;0x0000)
ARRAY TEXT:C222(LbFormat;0x0000)
ARRAY TEXT:C222(TableList;0x0000)
ARRAY LONGINT:C221(TableListID;0x0000)
ARRAY LONGINT:C221($PictRef_aL;0x0000)
ARRAY TEXT:C222($PictName_aT;0x0000)
ARRAY TEXT:C222(LbPictureTxt;0x0000)
C_PICTURE:C286($Img)

For ($a;1;Get last table number:C254)
	If (Is table number valid:C999($a))
		APPEND TO ARRAY:C911(TableList;Table name:C256(Table:C252($a)))
		APPEND TO ARRAY:C911(TableListID;$a)
	End if 
End for 

PICTURE LIBRARY LIST:C564($PictRef_aL;$PictName_aT)

$img:=PIC_GetPicture ("img/icnAttributes32.png")
BarInformation:=THERM_Init ("Identifying Pictures coming from 4D Library";"")
Progress SET ICON (BarInformation;$Img)
$methodCount_l:=Size of array:C274(TableList)
$Progression:=0
$Pas:=1/($methodCount_l+1)

For ($a;1;Size of array:C274(TableList))
	
	ARRAY TEXT:C222(TbForms;0x0000)
	$Progression:=$Progression+$pas
	Progress SET PROGRESS (BarInformation;$Progression;"Analysis of "+TableList{$a};True:C214)
	
	NumTable:=TableListid{$a}
	
	If (NumTable>0)
		ZptTable:=Table:C252(TableListid{$a})
		FORM GET NAMES:C1167(ZptTable->;TbForms;*)
	Else 
		FORM GET NAMES:C1167(TbForms;*)
	End if 
	
	For ($b;1;Size of array:C274(TbForms))
		
		If (NumTable>0)
			
			RESOLVE POINTER:C394(ZptTable;$vaNomVar;$vlNumTable;$vlNumChamp)
			
			If ($vlNumTable>0)
				NomTable:="["+Table name:C256(ZptTable)+"]"
			End if 
			
		Else 
			
			NomTable:=""
			
		End if 
		
		If ((Not:C34(Nil:C315(ZPtTable)) & (NumTable>0)))  // pointeur sur la table
			FORM LOAD:C1103(ZPtTable->;TbForms{$b};*)  // formulaire table de la base hôte
		Else 
			FORM LOAD:C1103(TbForms{$b};*)  // formulaire projet de la base hôte
		End if 
		
		<>Txt_form:=TbForms{$b}
		<>PtTable:=ZptTable
		
		ARRAY TEXT:C222(<>tTxt_objects;0x0000)
		ARRAY POINTER:C280(<>tPtr_var;0x0000)
		ARRAY LONGINT:C221(<>tLon_pages;0x0000)
		ARRAY BOOLEAN:C223(<>bTailleVariable;0x0000)
		
		FORM GET OBJECTS:C898(<>tTxt_objects;<>tPtr_var;<>tLon_pages)
		
		For ($c;1;Size of array:C274(<>tTxt_objects))
			
			$Format:=OBJECT Get format:C894(*;<>tTxt_objects{$c})
			$Pos:=Position:C15(";?";$Format)
			
			If ($Pos>0)
				
				APPEND TO ARRAY:C911(LbFormat;$Format)
				APPEND TO ARRAY:C911(LbTableName;NomTable)
				APPEND TO ARRAY:C911(LbFormName;TbForms{$b})
				APPEND TO ARRAY:C911(LbObject;<>tTxt_objects{$c})
				APPEND TO ARRAY:C911(LbObjectType;Object_GetType (<>tTxt_objects{$c}))
				
				  // reacherche du nom de l'image dans la bibliothèque
				$pos2:=Position:C15(";";$Format;$Pos+1)
				$RefID:=Num:C11(Substring:C12($Format;$Pos;($pos2-$Pos)))
				$Lig:=Find in array:C230($PictRef_aL;$RefID)
				$PictName_T:=""
				
				If ($lig>0)
					$PictName_T:=$PictName_aT{$Lig}
				End if 
				
				APPEND TO ARRAY:C911(LbPictureTxt;$PictName_T)
				
			End if 
			
			If ((OBJECT Get type:C1300(*;<>tTxt_objects{$c})=2) & ((Substring:C12($Format;1;1)=":") | (Substring:C12($Format;1;1)="?")))
				
				APPEND TO ARRAY:C911(LbFormat;$Format)
				APPEND TO ARRAY:C911(LbTableName;NomTable)
				APPEND TO ARRAY:C911(LbFormName;TbForms{$b})
				APPEND TO ARRAY:C911(LbObject;<>tTxt_objects{$c})
				APPEND TO ARRAY:C911(LbObjectType;Object_GetType (<>tTxt_objects{$c}))
				APPEND TO ARRAY:C911(LbPictureTxt;$Format)
				
			End if 
		End for 
		
		FORM UNLOAD:C1299
		
	End for 
End for 

BarInformation:=0
Progress QUIT (BarInformation)

$Listbox_Name:="LB_Information"
LB_Init_Start ($Listbox_Name)

C_LONGINT:C283($vNomHeader;$vNomHeader1;$vNomHeader2;$vNomHeader3;$vNomHeader4;$vNomHeader5)
$vNomHeader:=1
$vNomHeader1:=2
$vNomHeader2:=3
$vNomHeader3:=4
$vNomHeader4:=5
$vNomHeader5:=6

LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;1;"Table";LbTableName;"Table";$vNomHeader)
LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;2;"Form";LbFormName;"Form";$vNomHeader1)
LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;3;"Object";LbObject;"Object";$vNomHeader2)
LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;4;"ObjectT";LbObjectType;"ObjectT";$vNomHeader3)
LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;5;"Format";LbFormat;"Format";$vNomHeader4)
LISTBOX INSERT COLUMN:C829(*;$Listbox_Name;6;"Picture";LbPictureTxt;"Picture";$vNomHeader5)

OBJECT SET TITLE:C194(*;"Table";"Table Name")
OBJECT SET TITLE:C194(*;"Form";"Form")
OBJECT SET TITLE:C194(*;"Object";"Object")
OBJECT SET TITLE:C194(*;"ObjectT";"Object Type")
OBJECT SET TITLE:C194(*;"Format";"Format")
OBJECT SET TITLE:C194(*;"Picture";"Picture Name")

LISTBOX SET COLUMN WIDTH:C833(*;"Table";120)
LISTBOX SET COLUMN WIDTH:C833(*;"Form";120)
LISTBOX SET COLUMN WIDTH:C833(*;"Object";180)
LISTBOX SET COLUMN WIDTH:C833(*;"ObjectT";180)
LISTBOX SET COLUMN WIDTH:C833(*;"Format";220)

For ($a;1;Size of array:C274(LbTableName))
	LISTBOX SET ROW COLOR:C1270(*;$Listbox_Name;$a;0x0000)
	LISTBOX SET ROW FONT STYLE:C1268(*;$Listbox_Name;$a;Plain:K14:1)
End for 

ARRAY LONGINT:C221($MyFormEvents;0x0000)
OBJECT SET EVENTS:C1239(*;$Listbox_Name;$MyFormEvents;Enable events disable others:K42:37)